%%
%% This is file `huncllig.mf',
%% generated with the docstrip utility.
%%
%% The original source files were:
%%
%% huncial.dtx  (with options: `lig')
%% 
%%  Copyright 1999 Peter R. Wilson
%% 
%%  This program is provided under the terms of the
%%  LaTeX Project Public License distributed from CTAN
%%  archives in directory macros/latex/base/lppl.txt.
%% 
%% Author: Peter Wilson (CUA)
%%         now at: peter.r.wilson@boeing.com
%% 


ligtable "`": "`"=:oct"134";
ligtable "'": "'"=:oct"042"; %% , "?" kern 2u#, "!" kern 2u#;

ligtable "-": "-"=:oct"173";
ligtable oct"173": "-"=:oct"174";

ligtable "f": "i"=:oct"014";


cmchar "Uncial closing quotes";
beginchar(oct"042",2u#+hstretch*(comma_width#+3dot_size#),4/3x_height#,0);
adjust_fit(0,0);
pcshiftx:=u;
x1=w-pcshiftx-(0.5hstretch*dot_size); y1=y2=h;
x2=x1-(2hstretch*dot_size);
draw_pcomma(1,dot_size,comma_width);  % right
draw_pcomma(2,dot_size,comma_width);  % left
penlabels(1,2);
endchar; % end of "''"


cmchar "Uncial opening quotes";
beginchar(oct"134",2u#+hstretch*(comma_width#+3dot_size#),4/3x_height#,0);
adjust_fit(0,0);
pcshiftx:=u;
x1=pcshiftx+(0.5hstretch*dot_size); y1=y2=h;
x2=x1+(2hstretch*dot_size);
draw_plq(1,dot_size,comma_width); % left
draw_plq(2,dot_size,comma_width); % right
penlabels(1,2);
endchar; % end of "``"


cmchar "Uncial hyphen";
beginchar("-",u#+hstretch*(0.8x_height#),x_height#,0);
adjust_fit(0,0);
pcshiftx:=u/2;
numeric alpha; alpha:=w/8;
pickup quill;
lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
x11=lft x1+alpha/2; y11=top y1-0.5thin;
x12=rt x2; y12=bot y1+0.5thin;
draw z1--z2;  % bar
%%draw_triangle(11,alpha);
%%draw_rutriangle(12,alpha);
penlabels(1,2);
endchar; % end of "-"


cmchar "Uncial en dash";
beginchar(oct"173",u#+hstretch*(x_height#),x_height#,0);
adjust_fit(0,0);
pcshiftx:=u/2;
numeric alpha; alpha:=w/8;
pickup quill;
lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
x11=lft x1+alpha/2; y11=top y1-0.5thin;
x12=rt x2; y12=bot y1+0.5thin;
draw z1--z2;  % bar
%%draw_triangle(11,alpha);
%%draw_rutriangle(12,alpha);
penlabels(1,2);
endchar; % end of "--"


cmchar "Uncial em dash";
beginchar(oct"174",u#+hstretch*(2x_height#),x_height#,0);
adjust_fit(0,0);
pcshiftx:=u/2;
numeric alpha; alpha:=w/8;
pickup quill;
lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
x11=lft x1+alpha/2; y11=top y1-0.5thin;
x12=rt x2; y12=bot y1+0.5thin;
draw z1--z2;  % bar
%%draw_triangle(11,alpha);
%%draw_rutriangle(12,alpha);
penlabels(1,2);
endchar; % end of "---"


cmchar "HUncial ligature fi";
beginchar(oct"014", 2u#+hstretch*(7/6x_height#+trijut#), (3/2x_height#), desc_depth#);
adjust_fit(0,0);
pcshiftx := u;
pickup quill;
lft x1=lft x2=pcshiftx+trijut;
top y1=2/3h; bot y2=-d;
z3=z4=z1;
rt x5=w-pcshiftx; top y5=h;
rt x6=w-pcshiftx-jut; y6=y4;
x7=x6; bot y7=0;
%%ductus:=true;
if ductus:
  pickup stylus;
fi
draw_tstem(1,2,srad);            % stem
draw_triserif(1,trijut);
draw_urswish(3,5);               % top bar
draw z4--z6;                     % bottom bar
draw_tstem(6,7,srad);            % stem
ductus:=false;
penlabels(1,2,3,4,5,6,7,100);
endchar; % end of "fi"


cmchar "HUncial ampersand";
beginchar("&", 2u#+hstretch*(5/3x_height#), x_height#, 0.5desc_depth#);
adjust_fit(0,0);
pcshiftx:=u;
numeric alpha; alpha:=3/5w-u;
pickup quill;
lft x1=pcshiftx; rt x3= alpha; y1=y3=h/2;
x2=x4=alpha/2; top y2=h; bot y4=0;
x3'=alpha;
bowl_stem(4,3');
rt x5=x4i; top y5=y4i;
rt x6=x4i; y5-y4=y2-y6;
x7=x1; y7=y1;
rt x8=w-pcshiftx; y8=y7;
lft x9=x5; y9=y5;
x10=0.5[x9,x8]; bot y10=-d;
x8'=x8;
bowl_stem(10,8');
x11=x10i; y11=y10i;
%%ductus:=true;
if ductus:
  pickup stylus;
fi
draw z5{-pdir}..{left}z4..z1..z2..z6;     % the E bowl
draw z7--z8;                              % the (top) bar
draw z8{left}..z9..z10{right}..{pdir}z11;       % the T bowl
ductus:=false;
penlabels(1,2,3,4,5,6,7,8,9,10,16,17,18,31,32,33);
endchar; % end of "&"

